#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <WiFi.h>
#include <WiFiClientSecure.h>
#include <ArduinoJson.h>
#include <WiFiManager.h>
#include <time.h>
#include <Fonts/FreeMonoBold9pt7b.h>

#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 64
#define OLED_RESET    -1

#define OLED_SDA 4
#define OLED_SCL 5
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

const char* ntpServer = "pool.ntp.org";
const long gmtOffset_sec = 2 * 3600; // UTC+2
const int daylightOffset_sec = 0;

const char* host = "www.bitstamp.net";
const char* btcApiUrl = "/api/v2/ticker/btcusd/";

float bitcoinPrice = 0.0;
int lastMinute = -1;

bool getLocalDateTime(String& formattedDate, String& formattedTime) {
  struct tm timeinfo;
  if (!getLocalTime(&timeinfo)) {
    formattedDate = "00/00/0000";
    formattedTime = "00:00:00";
    return false;
  }
  char timeStr[9], dateStr[11];
  strftime(timeStr, sizeof(timeStr), "%H:%M:%S", &timeinfo);
  strftime(dateStr, sizeof(dateStr), "%d/%m/%Y", &timeinfo);
  formattedDate = String(dateStr);
  formattedTime = String(timeStr);
  return true;
}

void fetchBitcoinPrice() {
  WiFiClientSecure client;
  client.setInsecure();
  if (!client.connect(host, 443)) {
    bitcoinPrice = 0.0;
    return;
  }
  client.print(String("GET ") + btcApiUrl + " HTTP/1.1\r\n" +
               "Host: " + host + "\r\n" +
               "Connection: close\r\n\r\n");

  String response;
  while (client.connected()) {
    String line = client.readStringUntil('\n');
    if (line == "\r") break;
  }
  while (client.available()) {
    response += client.readString();
  }
  client.stop();

  DynamicJsonDocument doc(1024);
  DeserializationError err = deserializeJson(doc, response);
  if (!err && doc.containsKey("last")) {
    bitcoinPrice = String(doc["last"].as<const char*>()).toFloat();
  } else {
    bitcoinPrice = 0.0;
  }
}

void setup() {
  Serial.begin(115200);
  Wire.begin(OLED_SDA, OLED_SCL);

  if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {
    Serial.println(F("Fallo de inicialización de la pantalla OLED"));
    for (;;);
  }
  display.display();
  delay(600);
  display.clearDisplay();

  WiFiManager wifiManager;
  wifiManager.autoConnect("BTCclockAP");
  Serial.println("Conectado a WiFi");

  configTime(gmtOffset_sec, daylightOffset_sec, ntpServer);
  struct tm timeinfo;
  while(!getLocalTime(&timeinfo)) delay(200);

  fetchBitcoinPrice();
}

void loop() {
  String formattedDate, formattedTime;
  if (!getLocalDateTime(formattedDate, formattedTime)) {
    Serial.println("Error obteniendo fecha/hora NTP");
    delay(1000);
    return;
  }

  int currentMinute = atoi(formattedTime.substring(3,5).c_str());
  if (currentMinute != lastMinute) {
    fetchBitcoinPrice();
    lastMinute = currentMinute;
  }

  display.clearDisplay();

  // Centrar "BTC PRICE"
  int16_t x1, y1;
  uint16_t w, h;
  display.setTextSize(1);
  display.setTextColor(SSD1306_WHITE);
  display.getTextBounds("BTC PRICE", 0, 0, &x1, &y1, &w, &h);
  int16_t centerX = (SCREEN_WIDTH - w) / 2;
  display.setFont(NULL); // Fuente estándar para el título
  display.setCursor(centerX, 0);
  display.print("BTC PRICE");

  // Centrar el precio (fuente grande)
  display.setFont(&FreeMonoBold9pt7b);
  char btcText[16];
  if (bitcoinPrice > 0.0) {
    snprintf(btcText, sizeof(btcText), "$%.2f", bitcoinPrice);
  } else {
    snprintf(btcText, sizeof(btcText), "ERROR");
  }
  display.getTextBounds(btcText, 0, 0, &x1, &y1, &w, &h);
  centerX = (SCREEN_WIDTH - w) / 2;
  display.setCursor(centerX, 37);
  display.setTextColor(SSD1306_WHITE);
  display.print(btcText);

  // Fecha y hora, centradas también
  display.setFont(NULL);
  display.setTextSize(1);
  String dateTime = formattedDate + " " + formattedTime;
  display.getTextBounds(dateTime, 0, 0, &x1, &y1, &w, &h);
  centerX = (SCREEN_WIDTH - w) / 2;
  display.setCursor(centerX, 55);
  display.print(dateTime);

  display.display();
  delay(1000);
}